home *** CD-ROM | disk | FTP | other *** search
/ Die Speccy' 97 / Die Speccy' 97.iso / amiga_system / the_aminet / comm / mail / netmail_13.lha / NetMail / Drivers / Edge.editor < prev    next >
Text File  |  1995-08-12  |  2KB  |  82 lines
  1. /*
  2. ** $VER: Edge.editor 1.1 (11.8.95)
  3. ** Copyright (c) 1995 Riccardo Solmi
  4. **
  5. */
  6.  
  7. OPTIONS RESULTS
  8. OPTIONS FAILAT 21
  9.  
  10. cmd = 'Edge'
  11. IF ~EXISTS(cmd) THEN DO
  12.    cmd = GetVar('NetMail/EdgeCmd')
  13.    IF cmd = 0 | ~EXISTS(cmd) THEN DO
  14.       ADDRESS COMMAND 'SetEnv NetMail/EdgeCmd `Which "Edge"`'
  15.       cmd = GetVar('NetMail/EdgeCmd')
  16.       IF cmd = 0 THEN DO
  17.          ADDRESS COMMAND 'SetEnv NetMail/EdgeCmd `RequestFile Title "Select Edge command" Noicons`'
  18.          cmd = GetVar('NetMail/EdgeCmd')
  19.          IF cmd = 0 | ~EXISTS(cmd) THEN RETURN 2
  20.          ADDRESS COMMAND 'Copy QUIET ENV:NetMail/EdgeCmd ENVARC:NetMail/EdgeCmd'
  21.       END
  22.    END
  23. END
  24.  
  25. SELECT
  26.    WHEN UPPER(ARG(1)) = 'EDIT' THEN DO
  27.       PARSE ARG , file, port
  28.  
  29.       winpar  = ''
  30.       wininfo = GetVar('NetMail/EditorWin')
  31.       IF wininfo ~= 0 THEN DO
  32.          PARSE VAR wininfo pL pT pW pH .
  33.          winpar = 'LEFTEDGE' pL 'TOPEDGE' pT 'WIDTH' pW 'HEIGHT' pH
  34.       END
  35.  
  36.       IF ~EXISTS(file) THEN ADDRESS COMMAND 'ECHO >"'file'" ""'
  37.       IF SHOW('P', 'EDGE') THEN DO
  38.          IF ~SHOW('P', port) | ~ABBREV(port, 'EDGE') THEN DO
  39.             ADDRESS 'EDGE'
  40.             'New' winpar
  41.             port = RESULT
  42.          END
  43.          ADDRESS VALUE port
  44.          'Open "'file'" FORCE'
  45.       END
  46.       ELSE DO
  47.          ADDRESS COMMAND
  48.          '"'cmd'" "'file'"'
  49.          'WaitForPort EDGE'
  50.          IF RC ~= 0 THEN RETURN 5
  51.          ADDRESS 'EDGE'
  52.          'AddressOf'
  53.          port = RESULT
  54.          ADDRESS VALUE port
  55.          IF winpar ~= '' THEN 'ChangeWindow' winpar
  56.       END
  57.    END
  58.    WHEN UPPER(ARG(1)) = 'SAVE' THEN DO
  59.       PARSE ARG , port
  60.  
  61.       IF SHOW('P', port) & ABBREV(port, 'EDGE') THEN DO
  62.          ADDRESS VALUE port
  63.          'Save NOICON NOBACKUP'
  64.       END
  65.    END
  66.    WHEN UPPER(ARG(1)) = 'CLOSE' THEN DO
  67.       PARSE ARG , port
  68.  
  69.       IF SHOW('P', port) & ABBREV(port, 'EDGE') THEN DO
  70.          ADDRESS VALUE port
  71.          wininfo = GetVar('NetMail/EditorWin')
  72.          PARSE VAR wininfo pL pT pW pH cLTWH
  73.          'Window'
  74.          PARSE VAR RESULT 'X 'pL', Y 'pT', W 'pW', H 'pH','
  75.          CALL SetVar('NetMail/EditorWin', pL pT pW pH cLTWH)
  76.          'Flag _GE_Flags DormantQuit CLEAR'
  77.          'Close FORCE'
  78.       END
  79.    END
  80. END
  81. RETURN port
  82.